def buildAsLibrary = project.hasProperty('BUILD_AS_LIBRARY')
def buildAsApplication = !buildAsLibrary
if (buildAsApplication) {
    apply plugin: 'com.android.application'
}
else {
    apply plugin: 'com.android.library'
}

android {
    if (buildAsApplication) {
        namespace "fishrungames.shadowoverbishkek"
    }
    compileSdkVersion 37
    defaultConfig {
        minSdkVersion 21
        targetSdkVersion 37
        versionCode 4
        versionName "1.0.7"
        externalNativeBuild {
            /*ndkBuild {
                arguments "APP_PLATFORM=android-19"
                abiFilters 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64'
            }*/
             cmake {
                 arguments /*"-DANDROID_APP_PLATFORM=android-19",*/ "-DANDROID_STL=c++_static"
                 cppFlags "-std=c++17 -frtti -fexceptions"
                 abiFilters 'arm64-v8a', 'x86_64'
             }
        }
    }
    buildTypes {
        release {
            // Enables code optimizations.
            minifyEnabled = true
            // Enables resource shrinking.
            shrinkResources = true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    applicationVariants.all { variant ->
        tasks["merge${variant.name.capitalize()}Assets"]
            .dependsOn("externalNativeBuild${variant.name.capitalize()}")
    }
    if (!project.hasProperty('EXCLUDE_NATIVE_LIBS')) {
        sourceSets.main {
            jniLibs.srcDir 'libs'
        }
        externalNativeBuild {
            /*ndkBuild {
                path 'jni/Android.mk'
            }*/
             cmake {
                 path 'jni/CMakeLists.txt'
                 version '3.22.1'
             }
        }
       
    }
    lint {
        abortOnError false
    }

    if (buildAsLibrary) {
        libraryVariants.all { variant ->
            variant.outputs.all { output ->
                if (output.outputFileName != null && output.outputFileName.endsWith(".aar")) {
                    output.outputFileName = "fishrungames.shadowoverbishkek.aar"
                }
            }
        }
    }
}

dependencies {
    implementation 'androidx.core:core-splashscreen:1.0.1'
    implementation fileTree(include: ['*.jar'], dir: 'libs')
}